paul@0 | 1 | /* |
paul@0 | 2 | * Generate a VGA signal using a PIC32 microcontroller. |
paul@0 | 3 | * |
paul@0 | 4 | * Copyright (C) 2017 Paul Boddie <paul@boddie.org.uk> |
paul@0 | 5 | * |
paul@0 | 6 | * This program is free software: you can redistribute it and/or modify |
paul@0 | 7 | * it under the terms of the GNU General Public License as published by |
paul@0 | 8 | * the Free Software Foundation, either version 3 of the License, or |
paul@0 | 9 | * (at your option) any later version. |
paul@0 | 10 | * |
paul@0 | 11 | * This program is distributed in the hope that it will be useful, |
paul@0 | 12 | * but WITHOUT ANY WARRANTY; without even the implied warranty of |
paul@0 | 13 | * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
paul@0 | 14 | * GNU General Public License for more details. |
paul@0 | 15 | * |
paul@0 | 16 | * You should have received a copy of the GNU General Public License |
paul@0 | 17 | * along with this program. If not, see <http://www.gnu.org/licenses/>. |
paul@0 | 18 | */ |
paul@0 | 19 | |
paul@0 | 20 | #include "mips.h" |
paul@0 | 21 | #include "pic32.h" |
paul@35 | 22 | #include "vga.h" |
paul@0 | 23 | |
paul@0 | 24 | /* Disable JTAG functionality on pins. */ |
paul@0 | 25 | |
paul@0 | 26 | .section .devcfg0, "a" |
paul@0 | 27 | .word 0xfffffffb /* DEVCFG0<2> = JTAGEN = 0 */ |
paul@0 | 28 | |
paul@0 | 29 | /* |
paul@0 | 30 | Set the oscillator to be the FRC oscillator with PLL, with peripheral clock |
paul@21 | 31 | divided by 2, and FRCDIV+PLL selected. |
paul@0 | 32 | |
paul@0 | 33 | The watchdog timer (FWDTEN) is also disabled. |
paul@9 | 34 | |
paul@9 | 35 | The secondary oscillator pin (FSOSCEN) is disabled to avoid pin conflicts with |
paul@9 | 36 | RPB4. |
paul@0 | 37 | */ |
paul@0 | 38 | |
paul@0 | 39 | .section .devcfg1, "a" |
paul@21 | 40 | .word 0xff7fdfd9 /* DEVCFG1<23> = FWDTEN = 0; DEVCFG1<13:12> = FPBDIV<1:0> = 1; |
paul@9 | 41 | DEVCFG1<5> = FSOSCEN = 0; DEVCFG1<2:0> = FNOSC<2:0> = 001 */ |
paul@0 | 42 | |
paul@0 | 43 | /* |
paul@0 | 44 | Set the FRC oscillator PLL function with an input division of 4, an output |
paul@21 | 45 | division of 2, a multiplication of 24, yielding a multiplication of 3. |
paul@21 | 46 | |
paul@21 | 47 | The FRC is apparently at 16MHz and this produces a system clock of 48MHz. |
paul@0 | 48 | */ |
paul@0 | 49 | |
paul@0 | 50 | .section .devcfg2, "a" |
paul@21 | 51 | .word 0xfff9fffb /* DEVCFG2<18:16> = FPLLODIV<2:0> = 001; |
paul@21 | 52 | DEVCFG2<6:4> = FPLLMUL<2:0> = 111; |
paul@9 | 53 | DEVCFG2<2:0> = FPLLIDIV<2:0> = 011 */ |
paul@0 | 54 | |
paul@0 | 55 | .text |
paul@0 | 56 | .globl _start |
paul@36 | 57 | .extern init_framebuffer |
paul@35 | 58 | .extern init_framebuffer_with_pattern |
paul@41 | 59 | .extern screendata |
paul@41 | 60 | .extern blit_string |
paul@80 | 61 | .extern message0 |
paul@80 | 62 | .extern message1 |
paul@0 | 63 | |
paul@78 | 64 | .macro load_affected |
paul@78 | 65 | lw $v0, -4($k0) |
paul@78 | 66 | lw $v1, -8($k0) |
paul@78 | 67 | lw $s0, -12($k0) |
paul@78 | 68 | lw $s1, -16($k0) |
paul@78 | 69 | lw $s2, -20($k0) |
paul@78 | 70 | lw $s3, -24($k0) |
paul@78 | 71 | lw $t8, -28($k0) |
paul@78 | 72 | lw $ra, -32($k0) |
paul@78 | 73 | lw $sp, -36($k0) |
paul@81 | 74 | lw $gp, -40($k0) |
paul@78 | 75 | .endm |
paul@78 | 76 | |
paul@78 | 77 | .macro load_state |
paul@78 | 78 | lw $s0, -44($k0) |
paul@78 | 79 | lw $s1, -48($k0) |
paul@78 | 80 | lw $s2, -52($k0) |
paul@78 | 81 | lw $s3, -56($k0) |
paul@81 | 82 | lw $gp, -60($k0) |
paul@78 | 83 | .endm |
paul@78 | 84 | |
paul@78 | 85 | .macro save_affected |
paul@78 | 86 | sw $v0, -4($k0) |
paul@78 | 87 | sw $v1, -8($k0) |
paul@78 | 88 | sw $s0, -12($k0) |
paul@78 | 89 | sw $s1, -16($k0) |
paul@78 | 90 | sw $s2, -20($k0) |
paul@78 | 91 | sw $s3, -24($k0) |
paul@78 | 92 | sw $t8, -28($k0) |
paul@78 | 93 | sw $ra, -32($k0) |
paul@78 | 94 | sw $sp, -36($k0) |
paul@81 | 95 | sw $gp, -40($k0) |
paul@78 | 96 | .endm |
paul@78 | 97 | |
paul@78 | 98 | .macro save_state |
paul@78 | 99 | sw $s0, -44($k0) |
paul@78 | 100 | sw $s1, -48($k0) |
paul@78 | 101 | sw $s2, -52($k0) |
paul@78 | 102 | sw $s3, -56($k0) |
paul@81 | 103 | sw $gp, -60($k0) |
paul@78 | 104 | .endm |
paul@78 | 105 | |
paul@0 | 106 | _start: |
paul@0 | 107 | /* |
paul@0 | 108 | Configure RAM. |
paul@0 | 109 | See: http://microchipdeveloper.com/32bit:mx-arch-exceptions-processor-initialization |
paul@0 | 110 | */ |
paul@0 | 111 | |
paul@0 | 112 | la $v0, BMXCON |
paul@10 | 113 | lw $v1, 0($v0) |
paul@48 | 114 | |
paul@48 | 115 | /* Set zero wait states for address setup. */ |
paul@48 | 116 | |
paul@10 | 117 | li $t8, ~(1 << 6) /* BMXCON<6> = BMXWSDRM = 0 */ |
paul@10 | 118 | and $v1, $v1, $t8 |
paul@48 | 119 | |
paul@48 | 120 | /* Set bus arbitration mode. */ |
paul@48 | 121 | |
paul@10 | 122 | li $t8, ~0b111 /* BMXCON<2:0> = BMXARB<2:0> = 0 */ |
paul@10 | 123 | ori $t8, $t8, 0b010 /* BMXCON<2:0> = BMXARB<2:0> = 2 */ |
paul@10 | 124 | and $v1, $v1, $t8 |
paul@10 | 125 | sw $v1, 0($v0) |
paul@0 | 126 | |
paul@0 | 127 | /* Enable caching. */ |
paul@0 | 128 | |
paul@14 | 129 | mfc0 $v1, CP0_CONFIG |
paul@14 | 130 | li $t8, ~CONFIG_K0 |
paul@14 | 131 | and $v1, $v1, $t8 |
paul@14 | 132 | ori $v1, $v1, CONFIG_K0_CACHABLE_NONCOHERENT |
paul@14 | 133 | mtc0 $v1, CP0_CONFIG |
paul@0 | 134 | nop |
paul@0 | 135 | |
paul@0 | 136 | /* Get the RAM size. */ |
paul@0 | 137 | |
paul@3 | 138 | la $v0, BMXDRMSZ |
paul@18 | 139 | lw $t0, 0($v0) |
paul@0 | 140 | |
paul@0 | 141 | /* Initialise the stack pointer. */ |
paul@0 | 142 | |
paul@3 | 143 | li $v1, KSEG0_BASE |
paul@18 | 144 | addu $sp, $t0, $v1 /* sp = KSEG0_BASE + RAM size */ |
paul@9 | 145 | |
paul@0 | 146 | /* Initialise the globals pointer. */ |
paul@0 | 147 | |
paul@0 | 148 | lui $gp, %hi(_GLOBAL_OFFSET_TABLE_) |
paul@0 | 149 | ori $gp, $gp, %lo(_GLOBAL_OFFSET_TABLE_) |
paul@0 | 150 | |
paul@5 | 151 | /* Set pins for output. */ |
paul@0 | 152 | |
paul@0 | 153 | jal init_pins |
paul@0 | 154 | nop |
paul@0 | 155 | |
paul@15 | 156 | la $t0, PORTA |
paul@15 | 157 | li $t1, (1 << 3) /* PORTA<3> = RA3 */ |
paul@15 | 158 | sw $t1, CLR($t0) |
paul@15 | 159 | |
paul@77 | 160 | jal init_io_pins |
paul@5 | 161 | nop |
paul@5 | 162 | |
paul@0 | 163 | /* Initialise the status register. */ |
paul@0 | 164 | |
paul@0 | 165 | jal init_interrupts |
paul@0 | 166 | nop |
paul@0 | 167 | |
paul@18 | 168 | /* Initialise framebuffer. */ |
paul@18 | 169 | |
paul@36 | 170 | la $a0, screendata |
paul@36 | 171 | jal init_framebuffer |
paul@18 | 172 | nop |
paul@18 | 173 | |
paul@18 | 174 | sync |
paul@18 | 175 | |
paul@0 | 176 | /* Initialise timer. */ |
paul@0 | 177 | |
paul@4 | 178 | jal init_timer2 |
paul@0 | 179 | nop |
paul@0 | 180 | |
paul@3 | 181 | /* Initialise DMA. */ |
paul@3 | 182 | |
paul@3 | 183 | jal init_dma |
paul@3 | 184 | nop |
paul@3 | 185 | |
paul@15 | 186 | /* Initialise OC1 and OC2. */ |
paul@5 | 187 | |
paul@9 | 188 | jal init_oc |
paul@3 | 189 | nop |
paul@3 | 190 | |
paul@77 | 191 | /* Initialise UART for debugging. */ |
paul@77 | 192 | |
paul@77 | 193 | jal init_uart |
paul@77 | 194 | nop |
paul@77 | 195 | |
paul@34 | 196 | /* Initialise the display state. */ |
paul@34 | 197 | |
paul@34 | 198 | li $s0, 0 /* line counter */ |
paul@34 | 199 | la $s1, vbp_active /* current event */ |
paul@38 | 200 | li $s2, SCREEN_BASE /* line address */ |
paul@38 | 201 | li $s3, SCREEN_BASE /* screen address */ |
paul@38 | 202 | |
paul@38 | 203 | /* Save the state for retrieval in the interrupt handler. */ |
paul@38 | 204 | |
paul@38 | 205 | li $k0, IRQ_STACK_LIMIT |
paul@78 | 206 | save_state |
paul@34 | 207 | |
paul@0 | 208 | /* Enable interrupts and loop. */ |
paul@0 | 209 | |
paul@0 | 210 | jal enable_interrupts |
paul@0 | 211 | nop |
paul@0 | 212 | |
paul@0 | 213 | jal handle_error_level |
paul@0 | 214 | nop |
paul@0 | 215 | |
paul@3 | 216 | /* Main program. */ |
paul@3 | 217 | |
paul@39 | 218 | li $a1, (3 << 24) /* counter ~= 50000000 */ |
paul@39 | 219 | li $a2, 0xffffff /* test counter at every 1/4 of range */ |
paul@39 | 220 | move $t2, $zero /* picture to show */ |
paul@3 | 221 | |
paul@3 | 222 | /* Monitoring loop. */ |
paul@0 | 223 | loop: |
paul@3 | 224 | addiu $a1, $a1, -1 /* counter -= 1 */ |
paul@39 | 225 | and $t1, $a2, $a1 |
paul@39 | 226 | bnez $t1, loop |
paul@0 | 227 | nop |
paul@0 | 228 | |
paul@15 | 229 | la $t0, PORTA |
paul@15 | 230 | li $t1, (1 << 3) /* PORTA<3> = RA3 */ |
paul@3 | 231 | sw $t1, INV($t0) |
paul@0 | 232 | |
paul@85 | 233 | la $v0, U1TXREG |
paul@77 | 234 | li $v1, '.' |
paul@85 | 235 | sw $v1, 0($v0) |
paul@77 | 236 | |
paul@39 | 237 | bnez $a1, loop /* until counter == 0 */ |
paul@39 | 238 | nop |
paul@39 | 239 | |
paul@39 | 240 | bnez $t2, _picture1 |
paul@39 | 241 | nop |
paul@39 | 242 | |
paul@39 | 243 | /* Show picture 0. */ |
paul@39 | 244 | |
paul@39 | 245 | la $a0, screendata |
paul@39 | 246 | jal init_framebuffer |
paul@39 | 247 | nop |
paul@41 | 248 | |
paul@41 | 249 | la $a0, message0 |
paul@41 | 250 | li $a1, SCREEN_BASE_KSEG0 |
paul@41 | 251 | jal blit_string |
paul@41 | 252 | nop |
paul@41 | 253 | |
paul@39 | 254 | li $t2, 1 |
paul@39 | 255 | j _next |
paul@39 | 256 | nop |
paul@39 | 257 | |
paul@39 | 258 | _picture1: |
paul@39 | 259 | /* Show picture 1. */ |
paul@39 | 260 | |
paul@39 | 261 | jal init_framebuffer_with_pattern |
paul@39 | 262 | nop |
paul@41 | 263 | |
paul@41 | 264 | la $a0, message1 |
paul@41 | 265 | li $a1, SCREEN_BASE_KSEG0 |
paul@41 | 266 | jal blit_string |
paul@41 | 267 | nop |
paul@41 | 268 | |
paul@39 | 269 | move $t2, $zero |
paul@39 | 270 | |
paul@0 | 271 | _next: |
paul@39 | 272 | li $a1, (3 << 24) /* counter ~= 50000000 */ |
paul@39 | 273 | li $a2, 0xffffff /* test counter at every 1/4 of range */ |
paul@0 | 274 | j loop |
paul@0 | 275 | nop |
paul@0 | 276 | |
paul@0 | 277 | |
paul@0 | 278 | |
paul@0 | 279 | init_pins: |
paul@1 | 280 | /* DEVCFG0<2> needs setting to 0 before the program is run. */ |
paul@0 | 281 | |
paul@3 | 282 | la $v0, CFGCON |
paul@0 | 283 | li $v1, (1 << 3) /* CFGCON<3> = JTAGEN = 0 */ |
paul@0 | 284 | sw $v1, CLR($v0) |
paul@0 | 285 | |
paul@3 | 286 | init_outputs: |
paul@3 | 287 | /* Remove analogue features from pins. */ |
paul@3 | 288 | |
paul@3 | 289 | la $v0, ANSELA |
paul@3 | 290 | sw $zero, 0($v0) /* ANSELA = 0 */ |
paul@3 | 291 | la $v0, ANSELB |
paul@3 | 292 | sw $zero, 0($v0) /* ANSELB = 0 */ |
paul@3 | 293 | |
paul@3 | 294 | la $v0, TRISA |
paul@3 | 295 | sw $zero, 0($v0) |
paul@0 | 296 | la $v0, TRISB |
paul@3 | 297 | sw $zero, 0($v0) |
paul@3 | 298 | |
paul@9 | 299 | la $v0, PORTA |
paul@9 | 300 | sw $zero, 0($v0) |
paul@9 | 301 | la $v0, PORTB |
paul@9 | 302 | sw $zero, 0($v0) |
paul@0 | 303 | |
paul@3 | 304 | jr $ra |
paul@0 | 305 | nop |
paul@0 | 306 | |
paul@0 | 307 | |
paul@0 | 308 | |
paul@85 | 309 | /* |
paul@85 | 310 | Timer initialisation. |
paul@85 | 311 | |
paul@85 | 312 | Timer2 is used to drive the output compare and DMA peripherals. |
paul@85 | 313 | */ |
paul@0 | 314 | |
paul@4 | 315 | init_timer2: |
paul@0 | 316 | |
paul@49 | 317 | /* Initialise Timer2 for sync pulses. */ |
paul@0 | 318 | |
paul@4 | 319 | la $v0, T2CON |
paul@4 | 320 | sw $zero, 0($v0) /* T2CON = 0 */ |
paul@0 | 321 | nop |
paul@0 | 322 | |
paul@4 | 323 | la $v0, TMR2 |
paul@4 | 324 | sw $zero, 0($v0) /* TMR2 = 0 */ |
paul@5 | 325 | |
paul@4 | 326 | la $v0, PR2 |
paul@0 | 327 | li $v1, HFREQ_LIMIT |
paul@4 | 328 | sw $v1, 0($v0) /* PR2 = HFREQ_LIMIT */ |
paul@0 | 329 | |
paul@0 | 330 | /* Start timer. */ |
paul@0 | 331 | |
paul@4 | 332 | la $v0, T2CON |
paul@5 | 333 | li $v1, (1 << 15) |
paul@5 | 334 | sw $v1, SET($v0) /* ON = 1 */ |
paul@5 | 335 | |
paul@5 | 336 | jr $ra |
paul@5 | 337 | nop |
paul@5 | 338 | |
paul@5 | 339 | |
paul@5 | 340 | |
paul@5 | 341 | /* |
paul@5 | 342 | Output compare initialisation. |
paul@5 | 343 | |
paul@15 | 344 | Timer2 will be used to trigger two events using OC1: one initiating the hsync |
paul@9 | 345 | pulse, and one terminating the pulse. The pulse should appear after the line |
paul@9 | 346 | data has been transferred using DMA, but this is achieved by just choosing |
paul@9 | 347 | suitable start and end values. |
paul@5 | 348 | |
paul@49 | 349 | Using OC2, Timer2 triggers a level shifting event and OC2 is reconfigured to |
paul@48 | 350 | reverse the level at a later point. In this way, the vsync pulse is generated |
paul@48 | 351 | and is synchronised to the display lines. |
paul@85 | 352 | |
paul@85 | 353 | The OC1 interrupt is used to update the state machine handling the display, |
paul@85 | 354 | also invoking the address update routine at the end of each visible display |
paul@85 | 355 | line, changing the source address of the DMA channel. |
paul@5 | 356 | */ |
paul@5 | 357 | |
paul@9 | 358 | init_oc: |
paul@15 | 359 | /* Disable OC1 interrupts. */ |
paul@9 | 360 | |
paul@85 | 361 | li $v1, (1 << 7) |
paul@9 | 362 | |
paul@85 | 363 | la $v0, IEC0 |
paul@85 | 364 | sw $v1, CLR($v0) /* IEC0<7> = OC1IE = 0 */ |
paul@9 | 365 | la $v0, IFS0 |
paul@85 | 366 | sw $v1, CLR($v0) /* IFS0<7> = OC1IF = 0 */ |
paul@9 | 367 | |
paul@15 | 368 | /* Initialise OC1. */ |
paul@9 | 369 | |
paul@15 | 370 | la $v0, OC1CON |
paul@15 | 371 | li $v1, 0b101 /* OC1CON<2:0> = OCM<2:0> = 101 (dual compare, continuous pulse) */ |
paul@9 | 372 | sw $v1, 0($v0) |
paul@9 | 373 | |
paul@9 | 374 | /* Pulse start and end. */ |
paul@9 | 375 | |
paul@15 | 376 | la $v0, OC1R |
paul@9 | 377 | li $v1, HSYNC_END /* HSYNC_START for positive polarity */ |
paul@9 | 378 | sw $v1, 0($v0) |
paul@9 | 379 | |
paul@15 | 380 | la $v0, OC1RS |
paul@9 | 381 | li $v1, HSYNC_START /* HSYNC_END for positive polarity */ |
paul@9 | 382 | sw $v1, 0($v0) |
paul@9 | 383 | |
paul@85 | 384 | /* Enable interrupt for address updating. */ |
paul@85 | 385 | |
paul@85 | 386 | la $v0, IPC1 |
paul@85 | 387 | li $v1, (0b11111 << 16) |
paul@85 | 388 | sw $v1, SET($v0) /* OC1IP = 7; OC1IS = 3 */ |
paul@85 | 389 | |
paul@85 | 390 | la $v0, IEC0 |
paul@85 | 391 | li $v1, (1 << 7) |
paul@85 | 392 | sw $v1, SET($v0) /* IEC0<7> = OC1IE = 1 */ |
paul@85 | 393 | |
paul@15 | 394 | /* OC1 is enabled. */ |
paul@9 | 395 | |
paul@15 | 396 | la $v0, OC1CON |
paul@9 | 397 | li $v1, (1 << 15) |
paul@9 | 398 | sw $v1, SET($v0) |
paul@9 | 399 | |
paul@9 | 400 | /* Disable OC2 interrupts. */ |
paul@5 | 401 | |
paul@85 | 402 | li $v1, (1 << 12) |
paul@5 | 403 | |
paul@85 | 404 | la $v0, IEC0 |
paul@85 | 405 | sw $v1, CLR($v0) /* IEC0<12> = OC2IE = 0 */ |
paul@5 | 406 | la $v0, IFS0 |
paul@85 | 407 | sw $v1, CLR($v0) /* IFS0<12> = OC2IF = 0 */ |
paul@5 | 408 | |
paul@5 | 409 | /* Initialise OC2. */ |
paul@5 | 410 | |
paul@5 | 411 | la $v0, OC2CON |
paul@9 | 412 | li $v1, 0b010 /* OC2CON<2:0> = OCM<2:0> = 010 (single compare, output driven low) */ |
paul@5 | 413 | sw $v1, 0($v0) |
paul@5 | 414 | |
paul@9 | 415 | /* Set pulse position. */ |
paul@5 | 416 | |
paul@5 | 417 | la $v0, OC2R |
paul@9 | 418 | sw $zero, 0($v0) |
paul@5 | 419 | |
paul@9 | 420 | /* Enable OC2 later. */ |
paul@5 | 421 | |
paul@5 | 422 | jr $ra |
paul@5 | 423 | nop |
paul@5 | 424 | |
paul@77 | 425 | init_io_pins: |
paul@5 | 426 | /* Unlock the configuration register bits. */ |
paul@5 | 427 | |
paul@5 | 428 | la $v0, SYSKEY |
paul@5 | 429 | sw $zero, 0($v0) |
paul@5 | 430 | li $v1, 0xAA996655 |
paul@5 | 431 | sw $v1, 0($v0) |
paul@5 | 432 | li $v1, 0x556699AA |
paul@5 | 433 | sw $v1, 0($v0) |
paul@5 | 434 | |
paul@5 | 435 | la $v0, CFGCON |
paul@5 | 436 | lw $t8, 0($v0) |
paul@5 | 437 | li $v1, (1 << 13) /* IOLOCK = 0 */ |
paul@5 | 438 | sw $v1, CLR($v0) |
paul@5 | 439 | |
paul@15 | 440 | /* Map OC1 to RPA0. */ |
paul@9 | 441 | |
paul@15 | 442 | la $v0, RPA0R |
paul@15 | 443 | li $v1, 0b0101 /* RPA0R<3:0> = 0101 (OC1) */ |
paul@9 | 444 | sw $v1, 0($v0) |
paul@9 | 445 | |
paul@15 | 446 | /* Map OC2 to RPA1. */ |
paul@5 | 447 | |
paul@15 | 448 | la $v0, RPA1R |
paul@15 | 449 | li $v1, 0b0101 /* RPA1R<3:0> = 0101 (OC2) */ |
paul@5 | 450 | sw $v1, 0($v0) |
paul@5 | 451 | |
paul@77 | 452 | /* Map U1TX to RPB15. */ |
paul@77 | 453 | |
paul@77 | 454 | la $v0, RPB15R |
paul@77 | 455 | li $v1, 0b0001 /* RPB15R<3:0> = 0001 (U1TX) */ |
paul@77 | 456 | sw $v1, 0($v0) |
paul@77 | 457 | |
paul@5 | 458 | la $v0, CFGCON |
paul@5 | 459 | sw $t8, 0($v0) |
paul@5 | 460 | |
paul@5 | 461 | /* Lock the oscillator control register again. */ |
paul@5 | 462 | |
paul@5 | 463 | la $v0, SYSKEY |
paul@5 | 464 | li $v1, 0x33333333 |
paul@5 | 465 | sw $v1, 0($v0) |
paul@0 | 466 | |
paul@0 | 467 | jr $ra |
paul@0 | 468 | nop |
paul@1 | 469 | |
paul@1 | 470 | |
paul@1 | 471 | |
paul@5 | 472 | /* |
paul@5 | 473 | Direct Memory Access initialisation. |
paul@3 | 474 | |
paul@15 | 475 | Write 160 pixels to PORTB for the line data. This is initiated by a timer |
paul@85 | 476 | interrupt. |
paul@3 | 477 | */ |
paul@3 | 478 | |
paul@3 | 479 | init_dma: |
paul@3 | 480 | /* Disable DMA interrupts. */ |
paul@1 | 481 | |
paul@3 | 482 | la $v0, IEC1 |
paul@15 | 483 | li $v1, (3 << 28) /* IEC1<29:28> = DMA1IE, DMA0IE = 0 */ |
paul@3 | 484 | sw $v1, CLR($v0) |
paul@3 | 485 | |
paul@3 | 486 | /* Clear DMA interrupt flags. */ |
paul@1 | 487 | |
paul@3 | 488 | la $v0, IFS1 |
paul@15 | 489 | li $v1, (3 << 28) /* IFS1<29:28> = DMA1IF, DMA0IF = 0 */ |
paul@3 | 490 | sw $v1, CLR($v0) |
paul@3 | 491 | |
paul@3 | 492 | /* Enable DMA. */ |
paul@3 | 493 | |
paul@3 | 494 | la $v0, DMACON |
paul@3 | 495 | li $v1, (1 << 15) |
paul@1 | 496 | sw $v1, SET($v0) |
paul@1 | 497 | |
paul@3 | 498 | /* |
paul@5 | 499 | Initialise a line channel. |
paul@5 | 500 | The line channel will be channel 0 (x = 0). |
paul@3 | 501 | |
paul@3 | 502 | Specify a priority of 3: |
paul@3 | 503 | DCHxCON<1:0> = CHPRI<1:0> = 3 |
paul@3 | 504 | |
paul@15 | 505 | Auto-enable the channel: |
paul@3 | 506 | DCHxCON<4> = CHAEN = 1 |
paul@3 | 507 | */ |
paul@3 | 508 | |
paul@3 | 509 | la $v0, DCH0CON |
paul@3 | 510 | li $v1, 0b10011 |
paul@3 | 511 | sw $v1, 0($v0) |
paul@3 | 512 | |
paul@5 | 513 | /* |
paul@15 | 514 | Initialise a level reset channel. |
paul@15 | 515 | The reset channel will be channel 1 (x = 1). |
paul@15 | 516 | |
paul@15 | 517 | Specify a priority of 3: |
paul@15 | 518 | DCHxCON<1:0> = CHPRI<1:0> = 3 |
paul@15 | 519 | |
paul@15 | 520 | Chain the channel to channel 0: |
paul@15 | 521 | DCHxCON<5> = CHCHN = 1 |
paul@15 | 522 | |
paul@15 | 523 | Allow the channel to receive events when disabled: |
paul@15 | 524 | DCHxCON<6> = CHAED = 1 |
paul@15 | 525 | */ |
paul@15 | 526 | |
paul@15 | 527 | la $v0, DCH1CON |
paul@15 | 528 | li $v1, 0b1100011 |
paul@15 | 529 | sw $v1, 0($v0) |
paul@15 | 530 | |
paul@15 | 531 | /* |
paul@5 | 532 | Initiate channel transfers when the initiating interrupt condition |
paul@5 | 533 | occurs: |
paul@9 | 534 | DCHxECON<15:8> = CHSIRQ<7:0> = timer 2 interrupt |
paul@11 | 535 | DCHxECON<4> = SIRQEN = 1 |
paul@20 | 536 | |
paul@20 | 537 | For now, however, prevent initiation by not setting SIRQEN. |
paul@5 | 538 | */ |
paul@3 | 539 | |
paul@3 | 540 | la $v0, DCH0ECON |
paul@20 | 541 | li $v1, (9 << 8) |
paul@3 | 542 | sw $v1, 0($v0) |
paul@1 | 543 | |
paul@3 | 544 | /* |
paul@15 | 545 | Initiate reset channel transfer when channel 0 is finished: |
paul@15 | 546 | DCHxECON<15:8> = CHSIRQ<7:0> = channel 0 interrupt |
paul@15 | 547 | DCHxECON<4> = SIRQEN = 1 |
paul@15 | 548 | */ |
paul@15 | 549 | |
paul@15 | 550 | la $v0, DCH1ECON |
paul@15 | 551 | li $v1, (60 << 8) | (1 << 4) |
paul@15 | 552 | sw $v1, 0($v0) |
paul@15 | 553 | |
paul@15 | 554 | /* |
paul@15 | 555 | The line channel has a cell size of the number bytes in a line: |
paul@9 | 556 | DCHxCSIZ<15:0> = CHCSIZ<15:0> = LINE_LENGTH |
paul@3 | 557 | */ |
paul@3 | 558 | |
paul@3 | 559 | la $v0, DCH0CSIZ |
paul@9 | 560 | li $v1, LINE_LENGTH |
paul@3 | 561 | sw $v1, 0($v0) |
paul@1 | 562 | |
paul@3 | 563 | /* |
paul@15 | 564 | The reset channel has a cell size of a single zero byte: |
paul@49 | 565 | DCHxCSIZ<15:0> = CHCSIZ<15:0> = 1 |
paul@15 | 566 | */ |
paul@15 | 567 | |
paul@15 | 568 | la $v0, DCH1CSIZ |
paul@15 | 569 | li $v1, 1 |
paul@15 | 570 | sw $v1, 0($v0) |
paul@15 | 571 | |
paul@15 | 572 | /* |
paul@11 | 573 | The source has a size identical to the cell size: |
paul@49 | 574 | DCHxSSIZ<15:0> = CHSSIZ<15:0> = LINE_LENGTH or 1 |
paul@3 | 575 | */ |
paul@3 | 576 | |
paul@3 | 577 | la $v0, DCH0SSIZ |
paul@9 | 578 | li $v1, LINE_LENGTH |
paul@3 | 579 | sw $v1, 0($v0) |
paul@3 | 580 | |
paul@15 | 581 | la $v0, DCH1SSIZ |
paul@15 | 582 | li $v1, 1 |
paul@15 | 583 | sw $v1, 0($v0) |
paul@15 | 584 | |
paul@3 | 585 | /* |
paul@5 | 586 | The source address is the physical address of the line data: |
paul@11 | 587 | DCHxSSA = physical(line data address) |
paul@3 | 588 | */ |
paul@1 | 589 | |
paul@3 | 590 | la $v0, DCH0SSA |
paul@38 | 591 | li $v1, SCREEN_BASE |
paul@38 | 592 | sw $v1, 0($v0) |
paul@3 | 593 | |
paul@3 | 594 | /* |
paul@15 | 595 | For the reset channel, a single byte of zero is transferred: |
paul@15 | 596 | DCHxSSA = physical(zero data address) |
paul@15 | 597 | */ |
paul@15 | 598 | |
paul@15 | 599 | la $v0, DCH1SSA |
paul@15 | 600 | la $v1, zerodata |
paul@15 | 601 | li $t8, KSEG0_BASE |
paul@15 | 602 | subu $v1, $v1, $t8 |
paul@15 | 603 | sw $v1, 0($v0) |
paul@15 | 604 | |
paul@15 | 605 | /* |
paul@11 | 606 | The destination has a size of 1 byte: |
paul@3 | 607 | DCHxDSIZ<15:0> = CHDSIZ<15:0> = 1 |
paul@3 | 608 | */ |
paul@3 | 609 | |
paul@71 | 610 | li $v1, 1 |
paul@71 | 611 | |
paul@3 | 612 | la $v0, DCH0DSIZ |
paul@3 | 613 | sw $v1, 0($v0) |
paul@3 | 614 | |
paul@15 | 615 | la $v0, DCH1DSIZ |
paul@15 | 616 | sw $v1, 0($v0) |
paul@15 | 617 | |
paul@3 | 618 | /* |
paul@15 | 619 | The destination address is the physical address of PORTB: |
paul@15 | 620 | DCHxDSA = physical(PORTB) |
paul@3 | 621 | */ |
paul@3 | 622 | |
paul@15 | 623 | li $v1, PORTB |
paul@3 | 624 | li $t8, KSEG1_BASE |
paul@3 | 625 | subu $v1, $v1, $t8 |
paul@71 | 626 | |
paul@71 | 627 | la $v0, DCH0DSA |
paul@3 | 628 | sw $v1, 0($v0) |
paul@3 | 629 | |
paul@15 | 630 | la $v0, DCH1DSA |
paul@15 | 631 | sw $v1, 0($v0) |
paul@15 | 632 | |
paul@85 | 633 | /* Enable interrupt for channel chaining. */ |
paul@7 | 634 | |
paul@3 | 635 | la $v0, DCH0INT |
paul@7 | 636 | li $v1, (1 << 19) /* CHBCIE = 1 */ |
paul@7 | 637 | sw $v1, 0($v0) |
paul@7 | 638 | |
paul@7 | 639 | la $v0, IPC10 |
paul@7 | 640 | li $v1, 0b11111 /* DMA0IP, DMA0IS = 0 */ |
paul@7 | 641 | sw $v1, CLR($v0) |
paul@85 | 642 | li $v1, 0b10011 /* DMA0IP = 4, DMA0IS = 3 */ |
paul@7 | 643 | sw $v1, SET($v0) |
paul@7 | 644 | |
paul@7 | 645 | la $v0, IEC1 |
paul@7 | 646 | li $v1, (1 << 28) /* IEC1<28> = DMA0IE = 1 */ |
paul@9 | 647 | sw $v1, SET($v0) |
paul@1 | 648 | |
paul@15 | 649 | /* Enable line channel. */ |
paul@3 | 650 | |
paul@3 | 651 | la $v0, DCH0CON |
paul@3 | 652 | li $v1, 0b10000000 |
paul@3 | 653 | sw $v1, SET($v0) |
paul@3 | 654 | |
paul@1 | 655 | jr $ra |
paul@1 | 656 | nop |
paul@1 | 657 | |
paul@15 | 658 | zerodata: |
paul@15 | 659 | .word 0 |
paul@15 | 660 | |
paul@1 | 661 | |
paul@1 | 662 | |
paul@85 | 663 | /* |
paul@85 | 664 | UART initialisation. |
paul@85 | 665 | |
paul@85 | 666 | Initialise UART transmission at 115200 baud. This is sensitive to the peripheral |
paul@85 | 667 | clock frequency. |
paul@85 | 668 | */ |
paul@77 | 669 | |
paul@77 | 670 | init_uart: |
paul@77 | 671 | /* Initialise UART. */ |
paul@77 | 672 | |
paul@77 | 673 | la $v0, U1BRG |
paul@77 | 674 | li $v1, 12 /* U1BRG<15:0> = BRG = (FPB / (16 * baudrate)) - 1 = (24000000 / (16 * 115200)) - 1 = 12 */ |
paul@77 | 675 | sw $v1, 0($v0) |
paul@77 | 676 | |
paul@77 | 677 | la $v0, U1MODE |
paul@77 | 678 | li $v1, (1 << 15) /* U1MODE<15> = ON = 0 */ |
paul@77 | 679 | sw $v1, CLR($v0) |
paul@77 | 680 | |
paul@77 | 681 | /* Start UART. */ |
paul@77 | 682 | |
paul@77 | 683 | la $v0, U1STA |
paul@77 | 684 | li $v1, (1 << 10) /* U1STA<10> = UTXEN = 1 */ |
paul@77 | 685 | sw $v1, SET($v0) |
paul@77 | 686 | |
paul@77 | 687 | la $v0, U1MODE |
paul@77 | 688 | li $v1, (1 << 15) /* U1MODE<15> = ON = 1 */ |
paul@77 | 689 | sw $v1, SET($v0) |
paul@77 | 690 | |
paul@77 | 691 | jr $ra |
paul@77 | 692 | nop |
paul@77 | 693 | |
paul@77 | 694 | |
paul@77 | 695 | |
paul@9 | 696 | /* Utilities. */ |
paul@9 | 697 | |
paul@9 | 698 | handle_error_level: |
paul@9 | 699 | mfc0 $t3, CP0_STATUS |
paul@9 | 700 | li $t4, ~(STATUS_ERL | STATUS_EXL) |
paul@9 | 701 | and $t3, $t3, $t4 |
paul@9 | 702 | mtc0 $t3, CP0_STATUS |
paul@9 | 703 | jr $ra |
paul@9 | 704 | nop |
paul@9 | 705 | |
paul@9 | 706 | enable_interrupts: |
paul@9 | 707 | mfc0 $t3, CP0_STATUS |
paul@9 | 708 | li $t4, ~STATUS_IRQ /* Clear interrupt priority bits. */ |
paul@9 | 709 | and $t3, $t3, $t4 |
paul@69 | 710 | ori $t3, $t3, (3 << STATUS_IRQ_SHIFT) |
paul@9 | 711 | li $t4, ~STATUS_BEV /* CP0_STATUS &= ~STATUS_BEV (use non-bootloader vectors) */ |
paul@9 | 712 | and $t3, $t3, $t4 |
paul@9 | 713 | ori $t3, $t3, STATUS_IE |
paul@9 | 714 | mtc0 $t3, CP0_STATUS |
paul@9 | 715 | jr $ra |
paul@9 | 716 | nop |
paul@9 | 717 | |
paul@9 | 718 | init_interrupts: |
paul@9 | 719 | mfc0 $t3, CP0_DEBUG |
paul@9 | 720 | li $t4, ~DEBUG_DM |
paul@9 | 721 | and $t3, $t3, $t4 |
paul@9 | 722 | mtc0 $t3, CP0_DEBUG |
paul@9 | 723 | |
paul@9 | 724 | mfc0 $t3, CP0_STATUS |
paul@11 | 725 | li $t4, STATUS_BEV /* BEV = 1 or EBASE cannot be set */ |
paul@9 | 726 | or $t3, $t3, $t4 |
paul@9 | 727 | mtc0 $t3, CP0_STATUS |
paul@9 | 728 | |
paul@9 | 729 | la $t3, exception_handler |
paul@9 | 730 | mtc0 $t3, CP0_EBASE /* EBASE = exception_handler */ |
paul@9 | 731 | |
paul@9 | 732 | li $t3, 0x20 /* Must be non-zero or the CPU gets upset */ |
paul@9 | 733 | mtc0 $t3, CP0_INTCTL |
paul@9 | 734 | |
paul@9 | 735 | li $t3, CAUSE_IV /* IV = 1 (use EBASE+0x200 for interrupts) */ |
paul@9 | 736 | mtc0 $t3, CP0_CAUSE |
paul@9 | 737 | |
paul@9 | 738 | jr $ra |
paul@9 | 739 | nop |
paul@9 | 740 | |
paul@9 | 741 | |
paul@9 | 742 | |
paul@9 | 743 | /* Exception servicing. */ |
paul@9 | 744 | |
paul@9 | 745 | .section .flash, "a" |
paul@9 | 746 | |
paul@33 | 747 | /* TLB error servicing. */ |
paul@33 | 748 | |
paul@33 | 749 | tlb_handler: |
paul@9 | 750 | j exception_handler |
paul@9 | 751 | nop |
paul@9 | 752 | |
paul@9 | 753 | |
paul@9 | 754 | |
paul@33 | 755 | /* General exception servicing. */ |
paul@33 | 756 | |
paul@33 | 757 | .org 0x180 |
paul@33 | 758 | |
paul@33 | 759 | exception_handler: |
paul@33 | 760 | j exc_handler |
paul@33 | 761 | nop |
paul@33 | 762 | |
paul@33 | 763 | |
paul@45 | 764 | |
paul@9 | 765 | /* Interrupt servicing. */ |
paul@9 | 766 | |
paul@9 | 767 | .org 0x200 |
paul@9 | 768 | |
paul@9 | 769 | interrupt_handler: |
paul@9 | 770 | |
paul@78 | 771 | /* |
paul@78 | 772 | Save affected registers, restoring IRQ state and switching to the IRQ |
paul@78 | 773 | stack. |
paul@78 | 774 | */ |
paul@38 | 775 | |
paul@38 | 776 | li $k0, IRQ_STACK_LIMIT |
paul@78 | 777 | save_affected |
paul@78 | 778 | load_state |
paul@38 | 779 | li $sp, IRQ_STACK_TOP |
paul@38 | 780 | |
paul@85 | 781 | /* Check for the output compare interrupt condition. */ |
paul@9 | 782 | |
paul@75 | 783 | la $v0, IFS0 |
paul@75 | 784 | lw $v1, 0($v0) |
paul@85 | 785 | andi $v1, $v1, (1 << 7) /* OC1IF */ |
paul@85 | 786 | beqz $v1, irq_dma |
paul@9 | 787 | nop |
paul@9 | 788 | |
paul@75 | 789 | irq_handle: |
paul@75 | 790 | /* Clear the interrupt condition. */ |
paul@9 | 791 | |
paul@9 | 792 | sw $v1, CLR($v0) |
paul@9 | 793 | |
paul@75 | 794 | /* Increment the line counter. */ |
paul@47 | 795 | |
paul@47 | 796 | addiu $s0, $s0, 1 |
paul@47 | 797 | |
paul@75 | 798 | /* Jump to the event handler. */ |
paul@47 | 799 | |
paul@47 | 800 | jalr $s1 |
paul@47 | 801 | nop |
paul@47 | 802 | |
paul@85 | 803 | irq_dma: |
paul@85 | 804 | /* Clear the DMA channel completion condition. */ |
paul@85 | 805 | |
paul@85 | 806 | la $v0, IFS1 |
paul@85 | 807 | lw $v1, 0($v0) |
paul@85 | 808 | li $t8, (1 << 28) |
paul@85 | 809 | and $v1, $v1, $t8 |
paul@85 | 810 | beqz $v1, irq_exit |
paul@85 | 811 | nop |
paul@85 | 812 | |
paul@85 | 813 | sw $v1, CLR($v0) /* IFS1<28> = DMA0IF = 0 */ |
paul@85 | 814 | |
paul@85 | 815 | la $v0, DCH0INT |
paul@85 | 816 | lw $v1, 0($v0) |
paul@85 | 817 | andi $v1, $v1, (1 << 3) |
paul@85 | 818 | beqz $v1, irq_exit |
paul@85 | 819 | nop |
paul@85 | 820 | |
paul@85 | 821 | sw $v1, CLR($v0) /* CHBCIF = 0 */ |
paul@85 | 822 | |
paul@9 | 823 | irq_exit: |
paul@78 | 824 | /* |
paul@78 | 825 | Save IRQ state and restore the affected registers, switching back to the |
paul@78 | 826 | original stack. |
paul@78 | 827 | */ |
paul@38 | 828 | |
paul@38 | 829 | li $k0, IRQ_STACK_LIMIT |
paul@78 | 830 | save_state |
paul@78 | 831 | load_affected |
paul@38 | 832 | |
paul@9 | 833 | eret |
paul@9 | 834 | nop |
paul@9 | 835 | |
paul@9 | 836 | |
paul@9 | 837 | |
paul@9 | 838 | /* Event routines. */ |
paul@9 | 839 | |
paul@9 | 840 | /* The vertical back porch. */ |
paul@9 | 841 | |
paul@9 | 842 | vbp_active: |
paul@9 | 843 | /* Test for visible region. */ |
paul@9 | 844 | |
paul@9 | 845 | sltiu $v0, $s0, VISIBLE_START |
paul@9 | 846 | bnez $v0, _vbp_active_ret |
paul@9 | 847 | nop |
paul@9 | 848 | |
paul@9 | 849 | /* Start the visible region. */ |
paul@9 | 850 | |
paul@9 | 851 | la $s1, visible_active |
paul@9 | 852 | |
paul@17 | 853 | /* Reset the line address. */ |
paul@17 | 854 | |
paul@17 | 855 | move $s2, $s3 |
paul@17 | 856 | |
paul@43 | 857 | /* Update the source address. */ |
paul@43 | 858 | |
paul@43 | 859 | la $v0, DCH0SSA |
paul@43 | 860 | sw $s2, 0($v0) |
paul@43 | 861 | |
paul@71 | 862 | /* Enable the line channel for timer event transfer initiation. */ |
paul@71 | 863 | |
paul@71 | 864 | la $v0, DCH0ECON |
paul@71 | 865 | li $v1, (1 << 4) /* DCH0ECON<4> = SIRQEN = 1 */ |
paul@71 | 866 | sw $v1, SET($v0) |
paul@71 | 867 | |
paul@9 | 868 | _vbp_active_ret: |
paul@9 | 869 | jr $ra |
paul@9 | 870 | nop |
paul@9 | 871 | |
paul@9 | 872 | |
paul@9 | 873 | |
paul@9 | 874 | /* The visible region. */ |
paul@9 | 875 | |
paul@9 | 876 | visible_active: |
paul@9 | 877 | /* Test for front porch. */ |
paul@9 | 878 | |
paul@9 | 879 | sltiu $v0, $s0, VFP_START |
paul@75 | 880 | bnez $v0, visible_update_address |
paul@9 | 881 | nop |
paul@9 | 882 | |
paul@9 | 883 | /* Start the front porch region. */ |
paul@9 | 884 | |
paul@9 | 885 | la $s1, vfp_active |
paul@9 | 886 | |
paul@75 | 887 | /* Disable the line channel. */ |
paul@75 | 888 | |
paul@75 | 889 | la $v0, DCH0ECON |
paul@75 | 890 | li $v1, (1 << 4) /* DCH0ECON<4> = SIRQEN = 0 */ |
paul@75 | 891 | sw $v1, CLR($v0) |
paul@75 | 892 | |
paul@9 | 893 | _visible_active_ret: |
paul@9 | 894 | jr $ra |
paul@9 | 895 | nop |
paul@9 | 896 | |
paul@9 | 897 | |
paul@9 | 898 | |
paul@45 | 899 | /* DMA update routine. */ |
paul@45 | 900 | |
paul@45 | 901 | visible_update_address: |
paul@45 | 902 | |
paul@45 | 903 | /* |
paul@45 | 904 | Update the line data address if the line counter (referring to the |
paul@45 | 905 | next line) is even. |
paul@45 | 906 | */ |
paul@45 | 907 | |
paul@45 | 908 | andi $t8, $s0, 1 |
paul@45 | 909 | bnez $t8, _visible_update_ret |
paul@45 | 910 | nop |
paul@45 | 911 | |
paul@45 | 912 | /* Reference the next line and update the DMA source address. */ |
paul@45 | 913 | |
paul@45 | 914 | addiu $s2, $s2, LINE_LENGTH |
paul@45 | 915 | |
paul@45 | 916 | /* Test for wraparound. */ |
paul@45 | 917 | |
paul@45 | 918 | li $t8, (SCREEN_BASE + SCREEN_SIZE) |
paul@45 | 919 | sltu $t8, $s2, $t8 |
paul@45 | 920 | bnez $t8, _visible_dma_update |
paul@45 | 921 | nop |
paul@45 | 922 | |
paul@45 | 923 | /* Reset the source address. */ |
paul@45 | 924 | |
paul@45 | 925 | li $s2, SCREEN_BASE |
paul@45 | 926 | |
paul@45 | 927 | _visible_dma_update: |
paul@45 | 928 | |
paul@45 | 929 | /* Update the source address. */ |
paul@45 | 930 | |
paul@45 | 931 | la $v0, DCH0SSA |
paul@45 | 932 | sw $s2, 0($v0) |
paul@45 | 933 | |
paul@45 | 934 | _visible_update_ret: |
paul@75 | 935 | jr $ra |
paul@45 | 936 | nop |
paul@45 | 937 | |
paul@45 | 938 | |
paul@45 | 939 | |
paul@9 | 940 | /* Within the vertical front porch. */ |
paul@9 | 941 | |
paul@9 | 942 | vfp_active: |
paul@9 | 943 | /* Test for vsync. */ |
paul@9 | 944 | |
paul@9 | 945 | sltiu $v0, $s0, VSYNC_START |
paul@9 | 946 | bnez $v0, _vfp_active_ret |
paul@9 | 947 | nop |
paul@9 | 948 | |
paul@9 | 949 | /* Start the vsync. */ |
paul@9 | 950 | |
paul@9 | 951 | la $s1, vsync_active |
paul@9 | 952 | |
paul@9 | 953 | /* Bring vsync low when the next line starts. */ |
paul@9 | 954 | |
paul@9 | 955 | la $v0, OC2CON |
paul@9 | 956 | li $v1, 0b010 | (1 << 15) /* OC2CON<2:0> = OCM<2:0> = 010 (single compare, output driven low) */ |
paul@9 | 957 | sw $v1, 0($v0) |
paul@9 | 958 | |
paul@9 | 959 | _vfp_active_ret: |
paul@9 | 960 | jr $ra |
paul@9 | 961 | nop |
paul@9 | 962 | |
paul@9 | 963 | |
paul@9 | 964 | |
paul@9 | 965 | /* The vsync period. */ |
paul@9 | 966 | |
paul@9 | 967 | vsync_active: |
paul@9 | 968 | /* Test for front porch. */ |
paul@9 | 969 | |
paul@9 | 970 | sltiu $v0, $s0, VSYNC_END |
paul@9 | 971 | bnez $v0, _vsync_active_ret |
paul@9 | 972 | nop |
paul@9 | 973 | |
paul@9 | 974 | /* Start the back porch. */ |
paul@9 | 975 | |
paul@9 | 976 | move $s0, $zero |
paul@9 | 977 | la $s1, vbp_active |
paul@9 | 978 | |
paul@9 | 979 | /* Bring vsync high when the next line starts. */ |
paul@9 | 980 | |
paul@9 | 981 | la $v0, OC2CON |
paul@9 | 982 | li $v1, 0b001 | (1 << 15) /* OC2CON<2:0> = OCM<2:0> = 001 (single compare, output driven high) */ |
paul@9 | 983 | sw $v1, 0($v0) |
paul@9 | 984 | |
paul@9 | 985 | _vsync_active_ret: |
paul@9 | 986 | jr $ra |
paul@9 | 987 | nop |
paul@79 | 988 | |
paul@79 | 989 | |
paul@79 | 990 | |
paul@79 | 991 | /* Exception handler. */ |
paul@79 | 992 | |
paul@79 | 993 | exc_handler: |
paul@79 | 994 | mfc0 $t7, CP0_ERROREPC |
paul@79 | 995 | nop |
paul@85 | 996 | la $ra, exc_handler_end |
paul@79 | 997 | |
paul@79 | 998 | exc_write_word: |
paul@79 | 999 | li $t8, 32 |
paul@79 | 1000 | la $v0, U1TXREG |
paul@79 | 1001 | exc_loop: |
paul@79 | 1002 | addiu $t8, $t8, -4 |
paul@79 | 1003 | srlv $v1, $t7, $t8 /* $v1 = $t7 >> $t8 */ |
paul@79 | 1004 | andi $v1, $v1, 0xF |
paul@79 | 1005 | addiu $t9, $v1, -10 /* $t9 >= 10? */ |
paul@79 | 1006 | bgez $t9, exc_alpha |
paul@79 | 1007 | nop |
paul@79 | 1008 | exc_digit: |
paul@79 | 1009 | addiu $v1, $v1, 48 /* convert to digit: '0' */ |
paul@79 | 1010 | j exc_write |
paul@79 | 1011 | nop |
paul@79 | 1012 | exc_alpha: |
paul@79 | 1013 | addiu $v1, $v1, 55 /* convert to alpha: 'A' - 10 */ |
paul@79 | 1014 | exc_write: |
paul@79 | 1015 | sw $v1, 0($v0) |
paul@79 | 1016 | bnez $t8, exc_loop |
paul@79 | 1017 | nop |
paul@79 | 1018 | exc_loop_end: |
paul@85 | 1019 | li $v1, ' ' |
paul@79 | 1020 | sw $v1, 0($v0) |
paul@79 | 1021 | |
paul@79 | 1022 | exc_handler_end: |
paul@85 | 1023 | jr $ra |
paul@79 | 1024 | nop |